In the AL language for Microsoft Dynamics 365 Business Central, the List Data Type represents a strongly typed list of ordered objects accessible by index. Lists are unbounded, meaning their dimension (size) is not specified when declared.

A List can only be declared with simple types (Byte, Boolean, Char, Code, Date, DateFormula, DateTime, Decimal, Text, Time, etc.) and does not support holding instantiated records.

Lists are an efficient way to create and manage unbounded data structures with many practical uses.

Only a few days pass when I do not find a reason to use lists. One of my recent uses for a List was to store and process each unique value found in a delimited text value. For this, I split the delimited text into separate values and then copied them to a new list removing duplicates.

In this example, a value delimited by a comma (‘,’) or pipe (‘|’) is split into a list of unique values.

    procedure SplitValues()
    var
        UniqueValues: List of [Text];
        DelimitedText: Text;
        value: Text;
    begin
        DelimitedText := '12,34,56,24|12,56,89,56,23|12,34,22,34';
        UniqueValues := SplitUniqueValues(DelimitedText);

        foreach value in UniqueValues do
            Message(value);
    end;

    local procedure SplitUniqueValues(DelimitedText: Text): List of [Text]
    var
        UniqueValues: List of [Text];
        Values: List of [Text];
        Delimiters: Text;
        value: Text;
    begin
        Delimiters := ', |';
        Values := DelimitedText.Split(Delimiters.Split(' '));
        foreach value in Values do
            if not UniqueValues.Contains(value) then
                UniqueValues.Add(value);

        exit(UniqueValues);
    end;

Learn more about the List Data Type Here

Note: The code and information discussed in this article are for informational and demonstration purposes only. This content was created referencing Microsoft Dynamics 365 Business Central 2023 Wave 1 online.

Base64 is a group of binary-to-text encoding schemes representing binary data in an ASCII string format. Base64 data encoding is designed to survive transport through transport layers that are not 8-bit clean, such as mail bodies. Encoding the binary data to ASCII text helps ensure that the data remains intact without loss or modification during transport.

The most common use case for base64 encoding is when binary data must be sent over text-based systems, such as email, HTTP, or complex data stored in XML or JSON.

The principle behind Base64 encoding takes 3 bytes of binary data and represents them as 4 ASCII characters. This increases the size of the data by 33%, which is a significant drawback, but sometimes this is acceptable given the benefits.

Base64 Encoding and Decoding with AL for Business Central via codeunit 4110 “Base64 Convert”. The “Base64 Convert” codeunit has many overload methods to convert text to and from its base-64 representation.

page 50100 "Base64 Encoding"
{
    ApplicationArea = All;
    Caption = 'Base64 Encoding';
    PageType = Card;

    layout
    {
        area(content)
        {
            group(General)
            {
                Caption = 'General';
                grid(Columns)
                {
                    ShowCaption = false;
                    group(text)
                    {
                        ShowCaption = false;
                        field(FromText; FromText)
                        {
                            ApplicationArea = All;
                            Caption = 'From Text';
                            Editable = true;
                            MultiLine = true;
                        }
                        field(ToText; ToText)
                        {
                            ApplicationArea = All;
                            Caption = 'To Text';
                            Editable = false;
                            MultiLine = true;
                        }
                    }
                }
            }
        }
    }
    actions
    {
        area(Promoted)
        {
            actionref(Encoderef; Encode)
            {
            }
            actionref(Dencoderef; Decode)
            {
            }
        }
        area(Processing)
        {
            action(Encode)
            {
                ApplicationArea = All;
                Caption = 'Encode';
                Image = EncryptionKeys;

                trigger OnAction()
                begin
                    ToText := Base64Convert.ToBase64(FromText);
                end;


            }
            action(Decode)
            {
                ApplicationArea = All;
                Caption = 'Decode';
                Image = Text;

                trigger OnAction()
                begin
                    ToText := Base64Convert.FromBase64(FromText);
                end;
            }
        }
    }

    var
        FromText: Text;
        ToText: Text;
        Base64Convert: Codeunit "Base64 Convert";
}

Note: The code and information discussed in this article are for informational and demonstration purposes only. This content was created referencing Microsoft Dynamics 365 Business Central 2023 Wave 1 online.

In the AL programming language, region directives are used to organize code to a specific region or section of code. Regions can help developers keep track of and manage the code for different parts of an application. The Region Directives also mark a block of code that you can expand or collapse, which is helpful with readability or focusing on sections of code.

codeunit 50101 "DVLPR Region Directive"
{
    #region Return Letters
    procedure ReturnA(): Char
    begin
        exit('A');
    end;

    procedure ReturnB(): Char
    begin
        exit('B');
    end;

    procedure ReturnC(): Char
    begin
        exit('C');
    end;
    #endregion

    #region Return Numbers
    procedure Return1(): Integer
    begin
        exit(1);
    end;

    procedure Return2(): Integer
    begin
        exit(2);
    end;

    procedure Return3(): Integer
    begin
        exit(3);
    end;
    #endregion
}

A region block is marked with the #region directive and is closed with the #endregion directive.

Note: The code and information discussed in this article is for informational and demonstration purposes only. This content was created referencing Microsoft Dynamics 365 Business Central 2023 Wave 1 online.

In the AL programming language, preprocessor directives are used to make code conditional, suppress warnings, and enable code expansion and collapse. The AL preprocessor directives are grouped into conditional, regions, and pragmas categories. In this article, I’ll highlight Conditional Preprocessor Directives.

Conditional preprocessor directives are a feature in AL that allows developers to include or exclude parts of the code based on certain conditions. These directives are evaluated at compile-time and help manage different configurations or enable and disable certain features.

A conditional directive checks the value of a symbol to determine if code is included in the compilation. Symbols may be defined at the beginning of a source file to set the Symbol for the scope of that file, or they can be defined in the app.json file for global scope within the extension.

Symbols are defined globally with the preprocessorSymbols setting in the extensions App.json file.

Symbols are defined with the scope of a file with the #define directive at the beginning of a source file. Symbols may also be undefined with the #undef directive, which is useful in the case of a global directive that should not be applied to a specific file.

Conditional preprocessor directives in AL for Microsoft Dynamics 365 Business Central may also use the Logical Operators “AND” and “OR,” allowing developers to include or exclude code based on multiple preprocessor symbols within one conditional directive. (Thank you for the comment, navfreak.com)

#define SYMBOL2
#define SYMBOL3
codeunit 50102 "DVLPR My Stuff"
{
    procedure CompilerDirective()
    var
        MessageTxt: Text;
    begin
#if SYMBOL1 or SYMBOL2        // Code to include if Symbol1 or Symbol2 is defined
        MessageTxt += 'Symbol1 or Symbol2\';
#endif

#if SYMBOL2 and SYMBOL3      // Code to include if Symbol2 and Symbol3 are defined
        MessageTxt += 'Symbol2 and Symbol3';
#endif

        Message(MessageTxt);
    end;

Using Conditional Preprocessor Directives is considered Best Practices for Deprecation of AL Code.

Read more about the feature Conditional directives here.

Note: The code and information discussed in this article is for informational and demonstration purposes only. This content was created referencing Microsoft Dynamics 365 Business Central 2023 Wave 1 online.